Devious Devices Framework Development/Beta

*naaitsab* · June 8, 2021

3 hours ago, UnEvenSteven said:

Time for a new device that can hopefully be added to the framework in a future update.

Nice work. Hopefully the boxbinder set also made it's way in the framework after the authors approval so we can enjoy some shiny new things

*Kimy* · June 9, 2021

12 hours ago, naaitsab said:

Nice work. Hopefully the boxbinder set also made it's way in the framework after the authors approval so we can enjoy some shiny new things

I am working on this as we speak!

loniceraa · June 12, 2021

I've been having a bit of trouble with the DD animation filter, but I think I've found a solution that could be more broadly helpful.

The problem I'm having is that some mods' animation requests depend heavily on the "include" and "suppress" tags initially supplied, and if the filter has to overrule the animation, it loses that information. For example, let's say that a mod requests a rape animation on a female PC with two male NPCs. Let's say the mod requests animations using the following tags:

Include: Oral, Anal, Vaginal
Suppress: Lesbian, Gay, FFM, MFF, FFF, MMM
IncludeAll: False (at least one include tag required)

Now, let's say the female PC has an anal plug. Anecdotally, a lot of MMF threeway animations include the anal tag, but some do not. If the initially selected animation does include the anal tag, then DD wisely discards it, due to the anal plug. But then, the next requested animation by DD is as follows (with aggressive not required):

Include: (empty)
Suppress: Anal, Yoke, Armbinder
IncludeAll: True (all include tags required)

Frequently, for me, this results in unfortunate animations, such as MFF animations where one of the male rapists is now in a female role, being raped by one of the other attackers. Not a great result, though it doesn't happen every time, of course.

The solution I propose is to recover the tag information supplied by the initial animation request, and adjust it according to the restrictions DD correctly imposes. This would be easy if SexLab saved that information as a property to the thread controller, but unfortunately, it only saves the filtered list of animations, and presumably DD doesn't want to modify SexLab scripts. Fortunately, though, the tag information is still recoverable: it is saved in a text cache by sslAnimationSlots.

I implemented the code to recover and adjust the tags by modifying only the SelectValidAnimations() function in zadBQ00.psc (starting at line 1001), as follows:

Spoiler


; filter version of the animation selector
sslBaseAnimation[] function SelectValidAnimations(sslThreadController Controller, int count, sslBaseAnimation previousAnim, bool usingArmbinder, bool usingYoke,  bool HasBoundActors,  bool forceaggressive, bool permitOral, bool permitVaginal, bool permitAnal, bool permitBoobs)
	bool aggr = false				
	string includetag = ""
	sslBaseAnimation[] Sanims
	If previousAnim != none && previousAnim.HasTag("foreplay") 		
		; ok, this is causing trouble, as we don't really have a lot of bound foreplay animations. We...just don't pass on the tag for now, which will result in regular anims.
		; includetag = "foreplay"
		; libs.Log("Using only foreplay animations.")					
	Elseif forceaggressive || (previousAnim != none && previousAnim.HasTag("Aggressive") && libs.config.PreserveAggro)
		libs.Log("Using only aggressive animations.")					
		aggr = true		
	Endif  
	Bool IsCreatureAnim = previousAnim.HasTag("Creature")
	If IsCreatureAnim && HasBoundActors
		; it's a creature anim and some participants are bound, we can abort here, as there are no bound animations for creatures.
		return None
	Endif
	; Bound Animations need to be processed separately, since they are not registered in SexLab.
	if count > 1 && HasBoundActors
		libs.Log("Actor(s) are bound. Trying to set up bound animation.")
		Sanims = New sslBaseAnimation[1]
		; we have bound anims only for two actors, so we pick an animation only if we have two actors, otherwise we let the filter split the scene later on.
		If count == 2
			Sanims[0] = GetBoundAnim(Controller.Positions[0], Controller.Positions[1], permitOral, permitVaginal, permitAnal, permitBoobs)						
		Endif
		If Sanims[0] == None
			libs.log("Error: SelectValidAnimations could find no valid bound animations.")
			return None
		Else
			return Sanims
		Endif
	Endif
	
	;;;;;;;;;;;;;;;;;;;;;;;;;;;
	;;; begin modified code
	;;;;;;;;;;;;;;;;;;;;;;;;;;;
	; find the animation cache slot associated with the animation that was previously being played	
	float TimeToBeat = 0.0
	int index = -1
	int i = 0
	While i < 20
		; we must check if this cache slot is the slot that was used by our thread controller.
		; we cannot do this with certainty. we will start by comparing animation array lengths.
		If SexLab.AnimSlots.GetCacheSlot(i).Length == Controller.Animations.Length
			; if there are multiple cache slots with the same correct array length, we will use the most recently updated slot.
			string CacheText = SexLab.AnimSlots.CacheInfo(i)
			int TimeStartIndex = StringUtil.Find(CacheText, " -- Timestamp: ") + 15
			int TimeEndIndex = StringUtil.Find(CacheText, " -- Count: ")
			float CacheTime = StringUtil.Substring(CacheText, TimeStartIndex, TimeEndIndex - TimeStartIndex) as float

			If CacheTime > TimeToBeat
				TimeToBeat = CacheTime
				index = i
			EndIf
		EndIf
		
		; Debug.Trace("[Zad Trace]: AnimCache Length - " + SexLab.AnimSlots.GetCacheSlot(i).Length +", Controller Anim Length - " + Controller.Animations.Length + ", CacheText - " + SexLab.AnimSlots.CacheInfo(i) + ", TimeToBeat - " + TimeToBeat + ", index - " + index)
		i += 1
	EndWhile
	
	string suppresstag = ""
	bool RequireAll = True
	If Index >= 0
		; grab the filter used to search for the played animation, and parse the string
		string CorrectCacheText = SexLab.AnimSlots.CacheInfo(index)
		int FilterStartIndex = StringUtil.Find(CorrectCacheText, " -- Name: ") + 10
		int FilterEndIndex = StringUtil.Find(CorrectCacheText, " -- Timestamp: ")
		string FilterText = StringUtil.Substring(CorrectCacheText, FilterStartIndex, FilterEndIndex - FilterStartIndex)
		string[] FilterArray = PapyrusUtil.StringSplit(FilterText, ":")
		
		string OldInclude = FilterArray[1]
		suppresstag = FilterArray[2]
		RequireAll = (FilterArray[3] == "TRUE")

		; adjust the include string to remove DD conflicting tags
		If OldInclude
			string[] OldIncludeArray = PapyrusUtil.StringSplit(OldInclude)
			
			; don't handle aggression here
			OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Aggressive")
			
			If !permitVaginal
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Vaginal")
			EndIf
			If !permitAnal
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Anal")
			EndIf
			If !permitBoobs
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Boobjob")
			EndIf
			If !permitOral
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Oral")
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Blowjob")
			EndIf
			If usingYoke
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Pillory")
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Yoke")
			EndIf
			If usingArmbinder
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Pillory")
				OldIncludeArray = PapyrusUtil.RemoveString(OldIncludeArray, "Armbinder")
			EndIf
			
			string NewInclude = PapyrusUtil.StringJoin(OldIncludeArray)
			If NewInclude
				If includetag
					includetag = includetag + "," + NewInclude
				Else
					includetag = NewInclude
				EndIf
			EndIf
		EndIf
	EndIf
	;;;;;;;;;;;;;;;;;;
	;;; end modified code; except getSuppressString and SexLab.GetAnimationsByTags last parameters
	;;;;;;;;;;;;;;;;;;
	
	string tagString = getTagString(aggr, includetag)
	string suppressString = getSuppressString(aggr, usingArmbinder, usingYoke, permitOral, permitVaginal, permitAnal, permitBoobs, suppresstag)	
	; ok, we need to process private animations and masturbation as a special case as the tag system would otherwise be unable to call DDI or ZAP armbinder and yoke animations and also not exclude opposite gender masturbation/
	if count == 1 		
		libs.Log("Selecting masturbation animation.")
		If usingArmbinder ; she is wearing an armbinder
			Sanims = New sslBaseAnimation[1]
			Sanims[0] = SexLab.GetAnimationObject("DDArmbinderSolo")
			return Sanims
		Endif
		If usingYoke ; she is wearing a yoke
			Sanims = New sslBaseAnimation[1]
			Sanims[0] = SexLab.GetAnimationObject("DDYokeSolo")
			return Sanims
		Endif
		If !permitVaginal ;she is belted
			Sanims = New sslBaseAnimation[1]
			Sanims[0] = SexLab.GetAnimationObject("DDBeltedSolo")
			return Sanims
		Endif
		; if she is not wearing chastity, we need to filter the wrong gender
		tagString = "Solo," + tagString
		If Controller.Positions[0].GetLeveledActorBase().GetSex() == 1		
			suppressString = "M," + suppressString
		Elseif Controller.Positions[0].GetLeveledActorBase().GetSex() == 0
			suppressString = "F," + suppressString
		EndIf
	EndIf		
	If IsCreatureAnim
		; determine what creature it was and append its tag to the selection if it was a humanoid one, otherwise return an empty array.
		string crString = GetCreatureType(previousAnim)
		if crString != ""
			tagString += "," + crString
		Else
			libs.log("Creature animation with non-humanoid creatures in use. Cannot replace. Filtering aborted.")
			return None
		Endif
	Endif
	Sanims = SexLab.GetAnimationsByTags(count, tagString, suppressString, RequireAll)
	libs.log("Selecting SexLab animations with number of actors: " + count)
	libs.log("Selecting SexLab animations with tag string: " + tagString)
	libs.log("Selecting SexLab animations with suppress string: " + suppressString)			
	return Sanims
endfunction

Maybe there's an easier way to do this, but I couldn't find it. And the code above works fine and doesn't seem to have any performance problems. Using this, the tags requested by DD in the example above would be:

Include: Oral, Vaginal
Suppress: Lesbian, Gay, FFM, MFF, FFF, MMM, Anal, Yoke, Armbinder
IncludeAll: False

This results in a much better choice of new animation, at least in my testing (DD 5.1, Skyrim SE). There could of course be a good reason not to recover the tags, such as animation scarcity. I haven't found that to be a problem, and I don't have a huge number of animations installed, but I haven't tested this too extensively so far. But maybe there's another reason? I'm not sure.

Thanks for all your work on Devious Devices! Hopefully this is helpful. If not, or if posting code suggestions here is against the rules, let me know and I'll remove it ASAP.

Zaflis · June 12, 2021

I suggest making key crafting harder, even though you might have plan to redesign that whole thing later. It is however really quick to alter to make it somewhat balanced for the now. Currently all of them cost 1 iron ingot each.

This is a quick overrider ESP to change crafting recipes to:

Restraints key: 2 iron ingots, 2 steel ingots

Chastity key: 3 gold ingots, 3 moonstone ingots

Piercing removal kit: 2 iron ingots, 2 quicksilver ingots

This is nothing more than initial untested version which i feel will be better. If you want to change them yourself, feel free, or suggest better recipes for everyone. It should help having them highlighted for editing in TES5Edit:

DD-HarderKeys.zip

I noticed there are 3 different difficulties of recipes for keys but i don't know how the harder ones get used, if at all currently.

Edit: I don't think those are quite good yet, last i checked blacksmith today there was 0 moonstone, gold or quicksilver... I made this too difficult instead.

Edited June 12, 2021 by Zaflis

*Herowynne* · June 12, 2021

8 hours ago, anyway ayway said:

Frequently, for me, this results in unfortunate animations, such as MFF animations where one of the male rapists is now in a female role, being raped by one of the other attackers.

I have the same problem. I hope that @Kimy considers your solution to this problem.

*Kimy* · June 12, 2021

10 hours ago, anyway ayway said: