PetCollar

[Lauralin]

Is there anyway to get the enchantment for a collar that doesn't require the DLCs? Both of the options given for the meshes require one or more.

 

You don't need to use the esp files from those modes, just the mesh (and textures I think) which don't need any DLCs.

[yurik]

I'd have a small request...if you like it.

Could be a couple lines of (non interactive) dialogue added when pet collar triggers...

 

For example changing "XXX needs your services", to something more appropriate and possibly with 2-3 different sentences.

 

ty

This is among the things I want to see also. Now I'm figuring how to add proper replies to the topic. Ideas of what aroused followers / citizens / creatures might say when approaching the pet would be appreciated.

 

Yuni's Suggestion Hour:

 

Okay, here I am, with another simple suggestion. Sometimes, ya just don't want an important scene interrupted by someone needing service, then a sudden cock down your throat. I love the ability to add and remove the pet ability at will in the MCM.

 

A hotkey to add or remove it from the player would be very convenient though. Sometimes, ya start talking to Jarl Balgruuf, only to see that his Housecarl is kind of having a groin bulge, and if you don't do something fast, it's gonna be a very awkward speech Balgruuf gives while you're polshing his Housecarl's knob.

 

Just one of my usual suggestions as I think of a possible feature. A hotkey that enabled or disabled fucktoy would be the same effect.

 

Sidenote: My mannequins-don't-rape-me-anymore trick has had VERY mixed results. Sometimes putting them in that faction fixes it, but on one of my recent save files, it's stopped fixing it. I'm not sure why. Will give more info when I figure it out, but the mannequins that repeated-offender'd got markfordelete'd and disable'd. Not like I used them anyways.

I don't want an easy way to toggle the effect, I'd rather halt the process for the time. Notice followersScanner.anyActorInDialogueWithPlayer I just added to Fucktoy script:

 

 

Scriptname PetCollarFucktoyScript extends activemagiceffect

PetCollarConfigScript property petCollarConfig auto
SexLabFramework property SexLab auto
Quest property petCollarFollowersSearch auto
Quest property petCollarArousedActorsSearch auto
Faction property sla_Arousal auto
Package property petCollarFucktoyTravelToPlayer auto
Race property horseRace auto

Spell property petCollarFollowerBuff auto
Spell property petCollarFollowerBuffPlayer auto
Spell property petCollarHorseBuff auto
Spell property petCollarHorseBuffPlayer auto

Actor pet
Int petArousal
Actor[] sexActors
sslBaseAnimation[] sexAnims

Bool continue = True

Event OnEffectStart(actor t, actor c)
    pet = t
    if pet == SexLab.PlayerRef
        Debug.Notification("Your servitude has started")
    endif
    RegisterForSingleUpdate(Utility.RandomFloat(3, 30))
EndEvent

Event OnUpdate()
    if pet.IsInCombat() || !Game.IsLookingControlsEnabled()
        if continue
            RegisterForSingleUpdate(petCollarConfig.scannerFrequency)
        endif
    else
        PetCollarFollowersSearchScript followersScanner = petCollarFollowersSearch as PetCollarFollowersSearchScript
        followersScanner.Refresh(pet)
        if followersScanner.anyEnemyNearby
            if continue
                RegisterForSingleUpdate(petCollarConfig.scannerFrequency)
            endif        
        else
            if (pet == SexLab.PlayerRef && followersScanner.anyFollower) || (followersScanner.sexActors && followersScanner.sexActors.Length > 1)
                sexActors = followersScanner.sexActors
            else
                sexActors = (petCollarArousedActorsSearch as PetCollarArousedActorsSearchScript).GetArousedActors(pet)
            endif
            
            if FillActorsAndAnims(sexActors)
                if pet == SexLab.PlayerRef
                    if sexActors.Length > 2
                        Debug.Notification(sexActors.Length - 1 + " people need your service")
                    else
                        Debug.Notification(sexActors[1].GetDisplayName() + " needs your service")
                    endif
                else
                    if sexActors.Length > 2
                        Debug.Notification(sexActors.Length - 1 + " people need " + pet.GetDisplayName() + "'s service")
                    else
                        Debug.Notification(sexActors[1].GetDisplayName() + " needs " + pet.GetDisplayName() + "'s service")
                    endif
                endif

                Int playerIndex = sexActors.Find(SexLab.PlayerRef)
                if  playerIndex >=0 && playerIndex != 1; Player is a pet or last of >2 actors (followersScanner always adds Player last)
                    Int i = 0
                    while i < sexActors.Length
                        if i != playerIndex
                            ActorUtil.AddPackageOverride(sexActors[i], petCollarFucktoyTravelToPlayer, 99)
                            sexActors[i].EvaluatePackage()
                        endif
                        i += 1
                    endwhile
                    
                    i = 5
                    while sexActors[1].GetDistance(SexLab.PlayerRef) > 180 && i > 0
                        i -= 1
                        Utility.Wait(2)
                    endwhile

                    Actor anyActorInDialogueWithPlayer = followersScanner.anyActorInDialogueWithPlayer
                    if anyActorInDialogueWithPlayer
                        Debug.Notification("Waiting for you to finish talking with " + anyActorInDialogueWithPlayer.GetDisplayName())
                        i = petCollarConfig.scannerFrequency
                        while anyActorInDialogueWithPlayer.IsInDialogueWithPlayer() && i > 0 && !SexLab.PlayerRef.IsInCombat()
                            i -= 5
                            Utility.Wait(5)
                            Debug.Notification(i)
                        endwhile
                    endif

                    i = 0
                    while i < sexActors.Length
                        if i != playerIndex
                            ActorUtil.RemovePackageOverride(sexActors[i], petCollarFucktoyTravelToPlayer)
                            sexActors[i].EvaluatePackage()
                        endif
                        i += 1
                    endwhile

                    if SexLab.PlayerRef.IsInCombat()
                        if continue
                            RegisterForSingleUpdate(petCollarConfig.scannerFrequency)
                        endif
                        return
                    endif
                endif
                
                if playerIndex >= 0 && SexLab.PlayerRef.IsOnMount() && !SexLab.PlayerRef.Dismount()
                    SexLab.PlayerRef.PushActorAway(SexLab.PlayerRef, 0)
                endif

                if followersScanner.anyFollower && petCollarConfig.petBlessingEnabled
                    petArousal = pet.GetFactionRank(sla_Arousal)
                    RegisterForModEvent("OrgasmEnd_PetCollar", "FollowerBuff")            
                endif
                    SexLab.StartSex(sexActors, sexAnims, hook="PetCollar")
                if continue
                    RegisterForSingleUpdate(petCollarConfig.scannerTimeoutAfterSex)
                endif
            elseif continue
                if petCollarConfig.enableStatusNotifications && pet == SexLab.PlayerRef
                    if followersScanner.anyFollower
                        Debug.Notification("Your service is not yet needed")
                    else
                        Debug.Notification("You feel lonely")
                    endif
                endif
                RegisterForSingleUpdate(petCollarConfig.scannerFrequency)
            endif
        endif
    endif
EndEvent

Bool Function FillActorsAndAnims(Actor[] actors)
    if actors && actors.Length > 1
        sexAnims = SexLab.PickAnimationsByActors(actors, aggressive=petCollarConfig.useAggressiveAnimations)
        if sexAnims
            sexActors = actors
            return True
        else
            Actor[] actorsMinusLast
            if actors.Length == 5
                actorsMinusLast = new Actor[4]
                actorsMinusLast[1] = actors[1]
                actorsMinusLast[2] = actors[2]
                actorsMinusLast[3] = actors[3]
            elseif actors.Length == 4
                actorsMinusLast = new Actor[3]
                actorsMinusLast[1] = actors[1]
                actorsMinusLast[2] = actors[2]
            elseif actors.Length == 3
                actorsMinusLast = new Actor[2]
                actorsMinusLast[1] = actors[1]
            elseif actors.Length == 2
                if actors[0] == SexLab.PlayerRef
                    Debug.Notification("You do not know how to have sex with " + actors[1].GetDisplayName())
                else
                    Debug.Notification(actors[0].GetDisplayName() + " does not know how to have sex with " + actors[1].GetDisplayName())
                endif
                actorsMinusLast = new Actor[1]
            endif
            actorsMinusLast[0] = actors[0]
            FillActorsAndAnims(actorsMinusLast)
        endif
    else
        return False
    endif
EndFunction

Event OnEffectFinish(actor t, actor c)
    continue = False
EndEvent

Event FollowerBuff(string eventName, string argString, float argNum, form sender)
    if petArousal > 0
        sslThreadController controller = SexLab.HookController(argString)
        Int duration = (controller.TotalTime * 60) as Int
    
        if sexActors[1].GetRace() == horseRace
            petCollarHorseBuff.SetNthEffectDuration(0, duration); Stamina
            petCollarHorseBuff.SetNthEffectDuration(1, duration); Speed
            Int magnitude = petArousal * 2 + petArousal / 10 * SexLab.PlayerRef.GetLevel()
            petCollarHorseBuff.SetNthEffectMagnitude(0, magnitude)
            petCollarHorseBuff.SetNthEffectMagnitude(1, petArousal * 0.8)

            petCollarHorseBuff.Cast(sexActors[0], sexActors[1])
            
            if sexActors[0] == SexLab.PlayerRef
                petCollarHorseBuffPlayer.SetNthEffectDuration(0, duration)
                petCollarHorseBuffPlayer.SetNthEffectMagnitude(0, magnitude)
            
                petCollarHorseBuffPlayer.Cast(SexLab.PlayerRef, SexLab.PlayerRef)
            endif
        else
            petCollarFollowerBuff.SetNthEffectDuration(0, duration); Health
            Int magnitude = petArousal + petArousal / 20 * SexLab.PlayerRef.GetLevel()
            petCollarFollowerBuff.SetNthEffectMagnitude(0, magnitude)

            petCollarFollowerBuffPlayer.SetNthEffectDuration(0, duration)
            petCollarFollowerBuffPlayer.SetNthEffectMagnitude(0, magnitude)

            Int index = 1
            while index < sexActors.Length
                petCollarFollowerBuff.Cast(sexActors[0], sexActors[index])
                index += 1
            endwhile
            if sexActors[0] == SexLab.PlayerRef
                petCollarFollowerBuffPlayer.Cast(SexLab.PlayerRef, SexLab.PlayerRef)
            endif
        endif
    endif
    UnregisterForModEvent("OrgasmEnd_PetCollar")
EndEvent

 

 

If you're in a dialogue with someone (either as a pet or as a "taker"), the scripts goes to the wait loop.

Generally I try to avoid having waits in my code, so I might change it when I figure a better way.

PetCollar_v4.7.2beta1.zip

 

Is it actually possible to make the collar work on a Demonica character?

If SexLabs works with it, PetCollar will work too.

[TechBaNe]

 

Is it actually possible to make the collar work on a Demonica character?

If SexLabs works with it, PetCollar will work too.

 

 

I think this is more in reference to "will the collar fit on the Demonica body" as it's a Lady Body variant and not a CBBE/UNP/Bodyslide body. So while the effects would certainly work, there's no guarantee that the actual collar would show up nicely.

[alexvkj]

 

 

Is it actually possible to make the collar work on a Demonica character?

If SexLabs works with it, PetCollar will work too.

 

 

I think this is more in reference to "will the collar fit on the Demonica body" as it's a Lady Body variant and not a CBBE/UNP/Bodyslide body. So while the effects would certainly work, there's no guarantee that the actual collar would show up nicely.

 

 

Exactly!

And it is actually the only Item I need for my submissive scenarios

[yurik]

If it doesn't fit, you can replace it with a collar for your body - there is a list of meshes at the bottom of IMPLEMENTATION spoiler PetCollar uses, just replace & rename with the meshes of your preferable collar, the naming scheme is following:

*_f0.nif - female mesh lower body weight,

*_m1.nif - male upper weight,

*_g.nif - ground object, mesh that is shown when item is not equipped.

[alexvkj]

It seems I have to install Creation Kit 

But thanks, now I have an idea where to look.

[darkfender666]

 

I'd have a small request...if you like it.

Could be a couple lines of (non interactive) dialogue added when pet collar triggers...

 

For example changing "XXX needs your services", to something more appropriate and possibly with 2-3 different sentences.

 

ty

This is among the things I want to see also. Now I'm figuring how to add proper replies to the topic. Ideas of what aroused followers / citizens / creatures might say when approaching the pet would be appreciated.

 

 

 

 

I am quite terrible with that ._. sry.

But i might suggest to avoid using in game dialogues and keep is simple and fast as it is now with some text added..

That because there are already many mods trying to initiate sex via approach and dialogue and too many = CTD while as it is now its clean and fast.

[HounDog]

I'm finding an issue with 4.7.1: 

 

i tested this in a small cell with just the PC and 1 follower pet

 

- when the pet is over the threshold but the PC isn't, i occasionally see the message "[pet] needs [pet]'s service"

 

- when the pc goes over the threshold i get the prompt to fuck the pet but nothing happens and sometimes the message "2 people need [pet]'s service" appears but again, nothing happens. on this instance, if i select "carry on" the message "[pet] needs [pet]'s service" appears again

 

- Engaging the pet in sex by another method after a prompt failure will result in a ctd but waiting a minute or so or changing cells will make her available again.

 

- if the PC is over the threshold but the pet isn't, everything works fine and the scene continues as normal

 

It should be noted that this issue shows on a new game that i started with 4.7.1. On a previous save that i started with 4.5.2 and then upgraded to 4.7.1 i never saw any issues except that sometimes i had to click the prompt 2 times to get the scenes running.

 

It seems to me that the pet's own arousal is preventing the scenes from running because she is somehow "servicing" herself? Does it makes sense? 

[yurik]

I'm finding an issue with 4.7.1: 

 

i tested this in a small cell with just the PC and 1 follower pet

 

- when the pet is over the threshold but the PC isn't, i occasionally see the message "[pet] needs [pet]'s service"

 

- when the pc goes over the threshold i get the prompt to fuck the pet but nothing happens and sometimes the message "2 people need [pet]'s service" appears but again, nothing happens. on this instance, if i select "carry on" the message "[pet] needs [pet]'s service" appears again

 

- Engaging the pet in sex by another method after a prompt failure will result in a ctd but waiting a minute or so or changing cells will make her available again.

 

- if the PC is over the threshold but the pet isn't, everything works fine and the scene continues as normal

 

It should be noted that this issue shows on a new game that i started with 4.7.1. On a previous save that i started with 4.5.2 and then upgraded to 4.7.1 i never saw any issues except that sometimes i had to click the prompt 2 times to get the scenes running.

 

It seems to me that the pet's own arousal is preventing the scenes from running because she is somehow "servicing" herself? Does it makes sense? 

 

You are absolutely correct, the pet actually tried to service herself. And it is the 3-d time I'm fixing this. Every time after major rewrite I keep forgetting to update the scanner accordingly. Sorry for this issue.

Please grab the new 4.7.2 update.

 

[HounDog]

 

 

I'm finding an issue with 4.7.1: 

 

i tested this in a small cell with just the PC and 1 follower pet

 

- when the pet is over the threshold but the PC isn't, i occasionally see the message "[pet] needs [pet]'s service"

 

- when the pc goes over the threshold i get the prompt to fuck the pet but nothing happens and sometimes the message "2 people need [pet]'s service" appears but again, nothing happens. on this instance, if i select "carry on" the message "[pet] needs [pet]'s service" appears again

 

- Engaging the pet in sex by another method after a prompt failure will result in a ctd but waiting a minute or so or changing cells will make her available again.

 

- if the PC is over the threshold but the pet isn't, everything works fine and the scene continues as normal

 

It should be noted that this issue shows on a new game that i started with 4.7.1. On a previous save that i started with 4.5.2 and then upgraded to 4.7.1 i never saw any issues except that sometimes i had to click the prompt 2 times to get the scenes running.

 

It seems to me that the pet's own arousal is preventing the scenes from running because she is somehow "servicing" herself? Does it makes sense?

 

 

You are absolutely correct, the pet actually tried to service herself. And it is the 3-d time I'm fixing this. Every time after major rewrite I keep forgetting to update the scanner accordingly. Sorry for this issue.

Please grab the new 4.7.2 update.

 

Wow, Thank you for the fast reply, you know, this issue brings the idea of allowing(or not) pets to masturbate, possibly by asking for permission via prompt or dialogue or mcm configuration? and maybe shocking the pet if the permission was not granted?  masturbating NPCs are rare in sexlab but always a pleasure to watch!

 

Anyway, thanks again! please keep up the great work, this mod has been an sexlab essential for me since i first discovered it, Light, fast, entertaining and to the point! 

 

[HounDog]

Ok, i have another one:

 

Have 2 followers one of them a pet, i leave the pet outside a dungeon because she is not very useful in fights, while in the dungeon the follower goes over the threshold and i get the message "[follower] needs [pet]'s service", then follower disappears and returns a few minutes later with zero arousal (presumably to have sex with the pet). 

 

Not a big issue so far, but when i go back outside the pet is stuck in the sex animation she did with follower and she cannot do any other actions, if she follows she does it gliding over but still in the same position. Engaging a sex scene by another method fixed the glitched animation but from this point on pet collar scenes do not trigger anymore (get over threshold, get message, actors get close together, nothing happens)

 

Edit:

 

Did some more testing on this scenario and it seems that the scenes were not triggering because there were more than 2 aroused actors (including the pet) and not because of the glitched animation, so there are 2 different issues:

 

1 - followers are transported off-cell when they need the pet's service, this can lead to a glitched animation on the pet that's easily fixed by forcing another animation or by changing cells, in the case of the PC the pet will teleport to the PC but can lead to a ctd if the "teleporting" takes too long. Teleporting seems limited to an individual session meaning that the game will progress as normal with no prompts/pet requirements if the game is saved and then restarted while being in a different cell than the pet.

 

2 - Scenes will not trigger when there are more than two aroused actors (including the pet),  because the pet is including herself in the list to be serviced (the message says "3 people need [pet]'s service")

 

[yurik]

That's weird, because the pet scans for aroused actors in her own cell only. I'll look into this, thanks!

FYI, there's an option in SexLab's MCM to stop all active sex scenes, somewhere on the last page. Saves effort with the stucked animations.

[HounDog]

That's weird, because the pet scans for aroused actors in her own cell only. I'll look into this, thanks!

FYI, there's an option in SexLab's MCM to stop all active sex scenes, somewhere on the last page. Saves effort with the stucked animations.

you know, i've been thinking about it and my guess is that the teleporting may have something to do with the way EFF (which i use) handles followers, because it doesn't happen with followers that use their own system like Inigo or Sofia. In fact, (and i don't know if this is the correct behavior but i'm ok with it) the pet is only ever used by actors that are currently following me, which means i can leave her in a room full of aroused actors and she will be ignored. 

 

I actually tried the stop animations option but the pet wasn't stuck in an actual sex animation it was just like a sexy version of the half-t pose, kinda funny actually, i should have taken a screenshot...

 

Anyway, sorry about the bogus bug report, I guess that only leaves issue #2? or could that be related to eff as well? because i know you fixed something similar in 4.7.2? 

 

Thanks again

[alexvkj]

@yurik

 

After messing around in CK, I figured out, there is no Rendered Item for the PetCollar.

I tried to add some dialogs to a current follower where the player asks to become a pet.

Afterwards I wanted to equip the collar per script, but I see no effect at all when I do it with the inventory-item. Tried the same with the usual DD collar, it worked as intended.

 

I do it with:

libs.ManipulateGenericDevice(Game.GetPlayer(), KeylessCollar,  True)  where KeylessCollar-property set on the inventory item

 

Could you help me please?

[yurik]

I believe 'ManipulateGenericDevice' function finds the info on the rendered devices, keywords etc from the script attached to the item. And in my case it is a custom script ('PetCollarScript', with added electrocuting on fiddling with the collar functionality). So I suppose there are 2 options:
- replace my script with generic one ('zadCollarScript', and don't forget to re-fill the properties) but lose my added functionality
- try DD function for custom devices:
Function EquipDevice(actor akActor, armor deviceInventory, armor deviceRendered, keyword zad_DeviousDevice, bool skipEvents=false, bool skipMutex=false)
https://github.com/DeviousDevices/Docs/wiki/Basic-Commands
 
PS. I really hope to see your quest when it's done!

And integrate it into my mod

 

[alexvkj]

- try DD function for custom devices:

Function EquipDevice(actor akActor, armor deviceInventory, armor deviceRendered, keyword zad_DeviousDevice, bool skipEvents=false, bool skipMutex=false)

https://github.com/DeviousDevices/Docs/wiki/Basic-Commands

 

PS. I really hope to see your quest when it's done!

And integrate it into my mod

 

 

For EquipDevice I need the RenderedDevice which you don' t provide. I'll try to make it myself and then we'll see

The quest will be at the End rather simple, it's really just a probe of all that modding stuff. I prepare myself for Fallout 4

 

[yurik]

But I did, look for 'PetCollar_scriptInstance'.

[alexvkj]

Okay, I just found it myself

But it didn't work anyway.

 

libs.EquipDevice(libs.PlayerRef, KeylessCollarInventory, KeylessCollar, libs.zad_DeviousCollar)

 

No effect

[alexvkj]

I tried also just to put the collar in the player's inventory with:

 

libs.PlayerRef.Additem(KeylessCollarInventory)

 

Also no effect.

Changed property to zad_IronCollarInventory - works fine.

[pihwht]

@yurik

 

After messing around in CK, I figured out, there is no Rendered Item for the PetCollar.

I tried to add some dialogs to a current follower where the player asks to become a pet.

Afterwards I wanted to equip the collar per script, but I see no effect at all when I do it with the inventory-item. Tried the same with the usual DD collar, it worked as intended.

 

I do it with:

libs.ManipulateGenericDevice(Game.GetPlayer(), KeylessCollar,  True)  where KeylessCollar-property set on the inventory item

 

Could you help me please?

Deviously enslaved equips the petcollar with the function equippetcollar()

 

function equipPetCollar()

  libs.EquipDevice(player, petCollar, petCollar_script, libs.zad_DeviousCollar)

endFunction

[everforever]

Very interesting this mod
it would be possible
add this:

Ring of Master Type A, Type B and C
and Pet collar type A, type B and C

If the NPC or the player is wearing the ring type A
NPCs who are wearing the pet collar type A, will follow the NPC or player
are wearing the ring type A.

[yurik]

 

@yurik

 

After messing around in CK, I figured out, there is no Rendered Item for the PetCollar.

I tried to add some dialogs to a current follower where the player asks to become a pet.

Afterwards I wanted to equip the collar per script, but I see no effect at all when I do it with the inventory-item. Tried the same with the usual DD collar, it worked as intended.

 

I do it with:

libs.ManipulateGenericDevice(Game.GetPlayer(), KeylessCollar,  True)  where KeylessCollar-property set on the inventory item

 

Could you help me please?

Deviously enslaved equips the petcollar with the function equippetcollar()

 

function equipPetCollar()

  libs.EquipDevice(player, petCollar, petCollar_script, libs.zad_DeviousCollar)

endFunction

 

 

The function is declared in crdemodsmonitorscript and used by crdeplayermonitorscript. And it worked for me last time I tried Deviously Enslaved. It used standard Pet Collar though, not Keyless one.

I believe you can equip (Keyless) Pet Collar by Skyrim's base EquipItem function. Just don't forget to remove both inventory_item and rendered_item simultaneously if you will do it with script.

[alexvkj]

Still can't get it working with the PetCollar.

 

I attached the mod files, perhaps you can look into the matter yourself. It is currently set up on a standard zadCuffLeatherCollar and works fine with it. 

Basically, the mod adds a dialog option for the current follower where you can ask him/her to accept you as a pet.

Then you receive the collar and have to put it on yourself.

Just look at the quest vkj_PlaySubmissive.

 

I perceive the idea of consensual submitting to the followers, something like Mavias classic msexVeronica D/S mod. I think, the PetCollar can really handle most of the use cases.

 

To get a fully functional initial relese, I just need to get it working with PetCollar: AddItem, RemoveDevice. EquipDevice isn't necessary.

Playsubmissive.rar

[yurik]

I couldn't start the dialog - the topic is not present when I talk to my follower. I've got the vkjPlaySubmissive's init message though. Did I miss something?

 

 

 

But I noticed that you didn't list PetCollar.esp as master. Maybe this is the case?

You can add a non-esm mod as master with TesVSnip (Load your mod -> Edit -> Add Master...)

I added it for you: playsubmissive.esp

 

Alternatively, you can go with scripts like these:

Armor petCollar = Game.GetFormFromFile(0x00000D65 , "PetCollar.esp") as Armor
Armor petCollar_script = Game.GetFormFromFile(0x00000D64 , "PetCollar.esp") as Armor

vkjPlaySubmissive

 

 

Scriptname vkjPlaySubmissive extends Quest

zadlibs Property libs  Auto  
Actor currentMaster

Event OnInit()
	libs.NotifyPlayer("You are submissive. Get used to it")
EndEvent

function GiveToken(Actor master)
	Armor Token = Game.GetFormFromFile(0x00000D65 , "PetCollar.esp") as Armor
	libs.PlayerRef.Additem(Token)
	libs.NotifyPlayer("You feel a strong urge to put it on it right now")
	master.AddToFaction(MasterFaction)
	currentMaster = master
endFunction

function RemoveToken()
	Armor token = Game.GetFormFromFile(0x00000D65 , "PetCollar.esp") as Armor
	libs.ManipulateDevice(libs.PlayerRef, Token, false)
	libs.PlayerRef.RemoveItem(Token)
endFunction

function BeginSlavery()
	libs.NotifyPlayer("Now you belong to " + currentMaster.GetBaseObject().GetName())
endFunction

function EndSlavery()
	RemoveToken()
	currentMaster.RemoveFromFaction(MasterFaction)
endFunction


Faction Property MasterFaction  Auto  

 

 

[alexvkj]

Okay, that's surely the point I missed.

 

As for the missing dialogs, I had such issues with NMM. To resolve it I had to start Skse_loader from an Explorer window. Dunno yet what's wrong with it.

Starting conditions are: Quest Stage < 10 and Subject IsInFaction PlayerFollower. It worked with Erik the Slayer and Uthgerd the Unbroken. It didn't work with Arissa the wandering rogue. I'll look into alternatives, perhaps something like Teammate. That all modding stuff is very new to me