Jump to content

REDUNDANT OLD Preg/Offspring Beta Test Release

Halstrom

By Halstrom,
in Downloads - Fallout Sexout

Recommended Posts

Halstrom

Halstrom

Posted
  • Author
Posted

Ok for the braver souls out there, I have done little testing on this other than it starting up ok, I'll do some testing on it tommorrow.

 

Update 20150325.1:

 

SCR:

Fix to Lily being in Female Human Compaiion formlist

 

Pregnancy:

Added SetToPlayable to hide and show tokens by debug settings, PregDebug.esp is no longer used

Added Message to tell people to stop using PregDebug.esp

Fix to HoursToBirthing (untested)

Attempted fix to Birthing Animation (untested) found a flag causing the drawing weapon thing and also tried using a MISC Token instead of ARMOR to try avoid the reequip armor issue with NPC's

Added MaximumBellySize slider to MCM (untested)

 

OffSpring:

Added SetToPlayable to hide and show tokens by debug settings, OffSpringDebug.esp is no longer used (untested)

Added Message to tell people to stop using OffSpringDebug.esp

saviliana

saviliana

Posted
Posted

Brave soul is here.

 

Comfirm Med Scanner's Timer is working, birth animation is somewhat working.

 

The first birth animation not working right, seems like it stalled on tfc, but after the first birth and manually toggle tfc the rest of the birth animation are working nomally.

 

I guess you might want to check the SOPreg's camera position checksum or anything related on it.

 

And after birth exshaustion is locking up control, can wait in this action but locked other control input. It jeep keeps repeat the pushing animation.

 

Heres doc's debug record,but it too have preg's information in it so I post it up.

SexoutSpunk-Log--2015-3-26-0-12-3.txt

emes

emes

Posted
Posted

Yeah, I'll look into timer, birthing is screwed, no idea why it broke or how to fix it, I don't know squat about animations so they maybe broken forever...........

 

I took a stab at this, but didn't have much luck with it. (My game is a mess from all of my failed attempts to learn how to mod, so I'm never sure when bugs I come across are something I've caused or not.) I can offer a couple of observations I made while looking through the script, though:

 

In multiple births (somehow I got 24 mantis eggs...not sure if that's my modding caused), I notice that TFC is toggled each time. You might need some kind of a DoOnce flag for the session.

 

Should AI Packages be assigned to the player? I saw that it was being done (I think this causes the weapon drawing), but I wasn't sure if it was intentional.

 

I have no idea what code actually makes the animations play. I've been editing Arwen's Tweaks in my own game, and noticed the PlayIdle command for Stimpak and water-drinking animations, but I didn't see anything like that in here (and my attempts to use it didn't produce any results).

 

So, there, that's all a novice modder was able to make out from that code. Don't know if that helps at all. You might need to hit up someone on here with more experience with animations. ;)

Halstrom

Halstrom

Posted
  • Author
Posted

Brave soul is here.

 

Comfirm Med Scanner's Timer is working, birth animation is somewhat working.

 

The first birth animation not working right, seems like it stalled on tfc, but after the first birth and manually toggle tfc the rest of the birth animation are working nomally.

 

I guess you might want to check the SOPreg's camera position checksum or anything related on it.

 

And after birth exshaustion is locking up control, can wait in this action but locked other control input. It jeep keeps repeat the pushing animation.

 

Heres doc's debug record,but it too have preg's information in it so I post it up.

 

 

Yeah, I'll look into timer, birthing is screwed, no idea why it broke or how to fix it, I don't know squat about animations so they maybe broken forever...........

 

I took a stab at this, but didn't have much luck with it. (My game is a mess from all of my failed attempts to learn how to mod, so I'm never sure when bugs I come across are something I've caused or not.) I can offer a couple of observations I made while looking through the script, though:

 

In multiple births (somehow I got 24 mantis eggs...not sure if that's my modding caused), I notice that TFC is toggled each time. You might need some kind of a DoOnce flag for the session.

 

Should AI Packages be assigned to the player? I saw that it was being done (I think this causes the weapon drawing), but I wasn't sure if it was intentional.

 

I have no idea what code actually makes the animations play. I've been editing Arwen's Tweaks in my own game, and noticed the PlayIdle command for Stimpak and water-drinking animations, but I didn't see anything like that in here (and my attempts to use it didn't produce any results).

 

So, there, that's all a novice modder was able to make out from that code. Don't know if that helps at all. You might need to hit up someone on here with more experience with animations. ;)

 

Both of these posts were very helpful, thanks guys, I haven't actually found any cause or solutions to the problems presented but they did lead me to some other possible issues I've now fixed. The animations are actually called by adding the package with the animation in it to the actor, this worked fine 2 years ago when it was first added, but got broken somehow, I tried PlayIdle but couldn't get it to work at all.

 

I'll see if I can copy Doc's spunk DebugLog code and add that to pregnancy too.

 

This is the birthing code for anyone interested:

 

scn SexoutP4SBirthingEvent

ref rActor
int iCount
int iRandom
int iDoOnce
int iCountTarget
int iOkToRun
int iDeadTimer
int iRemoving
int iDebug
int iValidActor
int iCnt
ref rItem
int iBirthStage
float fDistanceToPlayer
int iBirthAnimation
int iActorSound
ref rPregType
ref rBirthType
int iBirthCount
int iSymbioteWorn
ref rUpperBody
ref rBackPack

int iWaterBroke
int iMessageCount
int iWaterBroke
int iVaginaClear
int iBodySuitBlock
int iBlockedVagina
ref rBlockedVagina
int iLockedVagina
ref rLockedVagina
int iClothCheck

Begin GameMode

Set rActor to GetContainer

if rActor && gPregStartCounter > 7 && iRemoving < 1
	Set iCountTarget to 199 + (200 * (SexoutP0QVAR.iBirthDuration / 100))
	Set iCount to iCount + 1
	if iCount > iCountTarget
		Set iCount to 0
		Set rBlockedVagina to HatParty
		Set rLockedVagina to HatParty
		Set rUpperBody to rActor.GetEquippedObject 2
		Set rBackPack to rActor.GetEquippedObject 7

		Set fDistanceToPlayer to rActor.GetDistance PlayerREF
		if rActor == PlayerREF
			Set fDistanceToPlayer to 1
		endif
		Set iDebug to 0
		if fDistanceToPlayer > 0 && fDistanceToPlayer < 900
			if SexoutP0QVAR.iDebug == 4
				Set iDebug to 4
			elseif SexoutP0QVAR.iDebug == 7 && rActor == PlayerREF
				Set iDebug to 4
			elseif SexoutP0QVAR.iDebug > 7
				Set iDebug to 4
			endif
		endif

		Set iValidActor to 0
		if rActor.GetIsSex Female || rActor.GetIsSex Male || rActor.GetIsCreature
			Set iValidActor to 1
		endif

; *** Check OK to run
		Set iOkToRun to 1
		if rActor.GetDead || iValidActor == 0
			Set iOkToRun to 0
			Set iDeadTimer to iDeadTimer + 1
			if iDeadTimer > 5
				Set iOkToRun to -1
			endif
		else
			Set iDeadTimer to 0
			if (rActor.NX_GetEVFo "Sexout:Started::spellTarget" != 0) || (rActor.GetItemCount 00SexoutActor > 0)
				Set iOkToRun to 0
			endif
 			if rActor != PlayerREF && rActor.GetInSameCell PlayerREF == 0
				Set iOkToRun to 0
			endif
		endif

		if iOkToRun > 0 && gPregBirthSelectHappening < 1 && gPregBirthPregHappening < 1 && (rActor.NX_GetEVFl "SOP:bPregBodySwapFlag" == 0) && (rActor.NX_GetEVFl "DOS:bSwappingFlag" == 0)
			Set iBirthStage to rActor.NX_GetEVFl "SOP:iBirthStage"
			Set iVaginaClear to 0
			Set iBodySuitBlock to 0
			if rUpperBody
				Set iBodySuitBlock to 1
				if (rActor.GetEquipped SexoutSLClothPregEffectOkForBirthOutfits)
					Set iBodySuitBlock to 0
				else
					Set iBirthStage to 2
				endif
			endif
			Set iBlockedVagina to 0
			if (rActor.GetEquipped SexoutSAPFISkinSuit)
				Set iBlockedVagina to 1
			endif
			if rActor.GetEquipped SexoutSLClothBindingsBlockedVaginal
				Set iBlockedVagina to 1
				Set iCnt to ListGetCount SexoutSLClothBindingsBlockedVaginal
				Label 1
				if iCnt > 0
					Set iCnt to iCnt - 1
					Set rItem to ListGetNthForm SexoutSLClothBindingsBlockedVaginal iCnt
					if rActor.GetEquipped rItem
						Set rBlockedVagina to rItem
						Set iBirthStage to 2
					endif
				goto 1
				endif
			endif
			Set iLockedVagina to 0
			if rActor.GetEquipped SexoutSLClothBindingsLockedVaginal
				Set iLockedVagina to 1
				Set iCnt to ListGetCount SexoutSLClothBindingsLockedVaginal
				Label 2
				if iCnt > 0
					Set iCnt to iCnt - 1
					Set rItem to ListGetNthForm SexoutSLClothBindingsLockedVaginal iCnt
					if rActor.GetEquipped rItem
						Set rLockedVagina to rItem
						Set iBirthStage to 2
					endif
				goto 2
				endif
			endif
			if iDebug == 4
				if iBirthStage < 2 || iBodysuitBlock > 0 || iBlockedVagina > 0 || iLockedVagina > 0
					DebugPrint "Preg4BirthPrep %n: Cloth %n, BodyS %1.0f, BVag %1.0f, LVag %1.0f" rActor rUpperBody iBodysuitBlock iBlockedVagina iLockedVagina
				endif
			endif

; *** Pre Birthing Contractions & Water Breaking
			if iBirthStage == 1
				Call SexoutP4SUDFBirthSelectType rActor
				Set iBirthStage to rActor.NX_GetEVFl "SOP:iBirthStage"
				Set rPregType to rActor.NX_GetEVFo "SOP:rPregType"
				Set rBirthType to rActor.NX_GetEVFo "SOP:rBirthType"
				Set iBirthCount to rActor.NX_GetEVFl "SOP:iBirthCount"
				Set iBirthAnimation to rActor.NX_GetEVFl "SOP:iBirthAnimation"

; *** Remove Spells, add Birth Message token & effect spell
				if rActor.IsSpellTarget SexoutP3ECramp
					rActor.Dispel SexoutP3ECramp
				endif
				if rActor.IsSpellTarget SexoutP3EMorningSickness
					rActor.Dispel SexoutP3EMorningSickness
				endif

				if iMessageCount < 1
					Set iRandom to (GetRandomPercent / 20)
					if iRandom == 1
						if rActor == PlayerREF
							MessageEx "The Contractions are stronger now making it difficult to walk"
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "The Contractions are making it hard for %n to walk" rActor
						endif
						Set iActorSound to 2
						Set iMessageCount to 1
						rActor.AddSpell SexoutP4EBirthingDue
					elseif iRandom == 2
						if rActor == PlayerREF
							MessageEx "The Contractions are strong, you moan loudly, you are about to start giving birth"
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "The Contractions force %n to grunt in pain as the birthing of her offspring begins" rActor
						endif
						Set iActorSound to 2
						Set iMessageCount to 1
						rActor.AddSpell SexoutP4EBirthingDue
					endif
				endif ; *** Contractions Messages

				if iWaterBroke < 1
					Set iRandom to (GetRandomPercent / 20)
					if iRandom == 1
						if rActor== PlayerREF
							ShowMessage SexoutP4BirthWaterBrokeZPlayer
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "%n moans loudly, her inner thighs suddenly drenched in water, her water just broke" rActor
						endif
						rActor.CIOS SexoutCumming
						Set iActorSound to 2
						Set iWaterBroke to 1
						rActor.AddSpell SexoutP4EBirthingDue
					elseif iRandom == 2
						if rActor == PlayerREF
							ShowMessage SexoutP4BirthWaterBrokeZPlayer
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "%n groans and grabs her crotch in surprise, her inner thighs are soaked as her water breaks" rActor
						endif
						rActor.CIOS SexoutCumming
						Set iActorSound to 2
						Set iWaterBroke to 1
						rActor.AddSpell SexoutP4EBirthingDue
					endif
				endif ; *** Water Breaking

				if iWaterBroke > 0 && iMessageCount > 0
					Set iBirthStage to 2
				endif

			elseif iBirthStage == 2 ; ***  PreBirthing Complete, Check if clothing is ok for birthing to happen
				if rActor == PlayerREF
					if iBodysuitBlock == 0 && iBlockedVagina == 0 && iLockedVagina == 0
						Set iVaginaClear to 1
					else
						if iLockedVagina
							ShowMessage SexoutP4BirthLockedClothesZPlayer
;							DebugPrint "Preg4BirthPrep %n: Locked %n, BodyS %1.0f, BVag %1.0f, LVag %1.0f" rActor rUpperBody iBodysuitBlock iBlockedVagina iLockedVagina
							Set iActorSound to 6
						else
							ShowMessage SexoutP4BirthStripClothesZPlayer
;							DebugPrint "Preg4BirthPrep %n: Cloth %n, BodyS %1.0f, BVag %1.0f, LVag %1.0f" rActor rUpperBody iBodysuitBlock iBlockedVagina iLockedVagina
							Set iActorSound to 2
						endif
					endif
				else ; *** NPC Actor
					if iBodysuitBlock == 0 && iBlockedVagina == 0 && iLockedVagina == 0
						Set iVaginaClear to 1
					else
						if iLockedVagina
							if fDistanceToPlayer > 0 && fDistanceToPlayer < 700 && GetRandomPercent > 90
								MessageEx "%n struggles to remove her clothes so she can give birth, but can't remove her %n" rActor rLockedVagina
								Set iActorSound to 6
							endif
						else
							if fDistanceToPlayer > 0 && fDistanceToPlayer < 700
								MessageEx "%n struggles from her clothes so she can give birth to her OffSpring" rActor
							endif
							if rActor.GetEquipped SexoutSAPFISkinSuit
								rActor.UnEquipItem SexoutSAPFISkinSuit
							endif
							if rUpperBody
								rActor.UnEquipItem rUpperBody 0 1
							endif
							if iBlockedVagina
								rActor.UnEquipItem rBlockedVagina 0 1
							endif
							Set iVaginaClear to 1
							Set iActorSound to 2
						endif
					endif
				endif ; *** Player or NPC ?
				if iVaginaClear < 1
					if rActor.IsSpellTarget SexoutP4EBirthTooTightClothes < 1
						rActor.CIOS SexoutP4EBirthTooTightClothes
					endif
				else
					rActor.Dispel SexoutP4EBirthTooTightClothes
					Set iBirthStage to 3
				endif

			elseif iBirthStage == 3 ; *** Pick from Pregnancies over 95% to be born
				Set gPregBirthSelectHappening to 1
				Call SexoutP4SUDFBirthSelectType rActor
				Set iBirthStage to rActor.NX_GetEVFl "SOP:iBirthStage"
				Set rPregType to rActor.NX_GetEVFo "SOP:rPregType"
				Set rBirthType to rActor.NX_GetEVFo "SOP:rBirthType"
				Set iBirthCount to rActor.NX_GetEVFl "SOP:iBirthCount"
				Set iBirthAnimation to rActor.NX_GetEVFl "SOP:iBirthAnimation"

				if (rActor.IsSpellTarget SexoutP4EBirthingHappening < 1)
					Set iBirthstage to 4
				else
					Set iBirthstage to 5
					if iDebug == 4
						DebugPrint "Preg4Birth %n: Repeated stage Skipping Animation Start" rActor 
					endif
				endif
				if rUpperBody || rActor.GetEquipped SexoutSAPFISkinSuit
					if (NX_IsInList SexoutSLClothPregEffectOkForBirthOutfits rUpperBody < 1) || (rActor.GetEquipped SexoutSAPFISkinSuit)
						Set iBirthstage to 2
					endif
				endif

			elseif iBirthStage == 4 ; *** Drop to ground & Start Animation
				rActor.NX_SetEVFl "SOP:bPregBirthAnim" 1
				ListAddForm SexoutPActorsBirthing rActor
				rActor.AddItem SexoutP4BirthingAnimationFlag 1 1
				rActor.Dispel SexoutP4EBirthingDue
				rActor.AddSpell SexoutP4EBirthingHappening 

				if iBirthAnimation < 2
					Set iRandom to GetRandomPercent
					if iRandom < 50
						if rActor == PlayerREF
							MessageEx "The Contractions force you to the ground in the throes of giving birth"
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "The Contractions force %n to the ground in the throes of giving birth" rActor
						endif
						Set iActorSound to 2
					elseif iRandom >= 50
						if rActor == PlayerREF
							MessageEx "The Contractions are too strong, you drop to the ground & moan loudly, you are about to start giving birth"
						elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
							MessageEx "The Contractions force %n to drop to the ground & wail in pain as the birthing of her offspring begins" rActor
						endif
						Set iActorSound to 2
					endif

					rActor.RemoveScriptPackage
					if rActor == PlayerREF
						DisablePlayerControls 1 1 1 0 0 1 1
						con_tfc ; It won't play the animation unless TFC is toggled on a little after it's started playing.
						if 1 == IsPC1stPerson ; in first person, force to 3rd
							TapControl 13
						endif
					else
						rActor.SetRestrained 1
					endif
					rActor.AddScriptPackage SexoutP4PACKBirthingAnimationF ; *** adding an AI script package to the Actor
					if iDebug == 4
						DebugPrint "Preg4Birth %n: BirthAnimationAdded" rActor
					endif

				elseif iBirthAnimation == 9 ; *** Add Egg birthing animation outfit
					if iDebug == 4
						DebugPrint "Preg4Birth Animation 9 Egg Start"
					endif
					rActor.AddItem SexoutSNudeEggImpregT3P0B3 1 1
					rActor.EquipItem SexoutSNudeEggImpregT3P0B3 1 1

				endif ; *** End Animation Options
				Set iBirthstage to 5

			elseif iBirthStage == 5 ; *** Offspring starts coming out
				Set iRandom to GetRandomPercent / 40
				if iRandom == 1
					if rActor == PlayerREF
						MessageEx "You pant & moan in pain as your OffSpring begins to breach your stretching Love canal"
					elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
						MessageEx "%n pants & moans in pain as her OffSpring begins to breach her stretching Love canal" rActor
					endif
					Set iBirthstage to 6
					Set iActorSound to 2
				elseif iRandom == 2
					if rActor == PlayerREF
						MessageEx "You cry out in pain as you push forcing your offspring from your painfully stretched pussy"
					elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
						MessageEx "%n cries out in pain as she pushes forcing her offspring from her painfully stretched pussy" rActor
					endif
					Set iBirthstage to 6
					Set iActorSound to 2
				endif

			elseif iBirthStage == 6 ; *** Offspring comes out
				Set iRandom to GetRandomPercent / 40
				if iRandom == 1
					if rActor == PlayerREF
						MessageEx "You scream as your OffSpring finally emerges from your straining pussy"
					elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
						MessageEx "%n screams as her OffSpring finally emerges from her straining pussy" rActor
					endif
					Set iActorSound to 6
				elseif iRandom == 2
					if rActor == PlayerREF
						MessageEx "You pant in relief as your final push sends your Offspring from your straining vagina"
					elseif fDistanceToPlayer > 0 && fDistanceToPlayer < 700
						MessageEx "%n pants in relief as her final push sends her Offspring from her straining vagina" rActor
					endif
					Set iActorSound to 6
				endif

; *** Call Birthing UDF to add correct offspring to inventory or world
				Set gPregBirthPregHappening to 1
				Call SexoutP4SUDFBirthPregType rActor rPregType
				Set iBirthCount to iBirthCount - 1

; *** Reset loop to Birth next Offspring if more than one?
				if iBirthCount > 0 ; *** || iPregCountEggSporePod > 1
					Set iBirthstage to 3
					if iDebug == 4
						DebugPrint "Preg4Birth %n: MultipleBirth Restarted, BirthCount %2.0f" rActor iBirthCount
					endif
				else
					Set iBirthstage to 7
					if iDebug == 4
						DebugPrint "Preg4Birth %n: End of Birthing, BirthCount %2.0f" rActor iBirthCount
					endif
				endif

; *** Remove Animations, Pregnancy & Effects
			elseif iBirthStage == 7
				if iBirthAnimation < 2
					if rActor == PlayerREF
						EnablePlayerControls
						con_tfc
;					else
;						rActor.SetRestrained 0
					endif
					rActor.SetRestrained 0
					rActor.RemoveScriptPackage
					rActor.PushActorAway rActor 2 ; *** Prevents NPC's crab walking
				elseif iBirthAnimation == 9
					rActor.UnEquipItem SexoutSNudeEggImpregT3P0B3 1 1
					rActor.RemoveItem SexoutSNudeEggImpregT3P0B3 1 1
				endif ; *** End Animation Options

				rActor.RemoveItem SexoutP4BirthingAnimationFlag 1 1
				ListRemoveForm SexoutPActorsBirthing rActor
				rActor.Dispel SexoutP4EBirthingHappening
				if rActor.IsSpellTarget SexoutP4EBirthExhaustion != 1
					rActor.AddSpell SexoutP4EBirthExhaustion
				endif
				if rActor.HasPerk SexoutSBroodMother != 1 
					rActor.AddPerk SexoutSBroodMother
				endif
				if iDebug == 4
					DebugPrint "Preg4Birth %n: BirthAnimationRemoved %1.0f" rActor iBirthAnimation
				endif
				Set iBirthAnimation to 0
				Set iBirthCount to 0
				Set rBirthType to HatParty
				rActor.NX_SetEVFl "SOP:iBirthAnimation" 0
				rActor.NX_SetEVFl "SOP:iBirthCount" 0
				rActor.NX_SetEVFo "SOP:rBirthType" HatParty
				rActor.NX_SetEVFo "SOP:rOffSpringAdded" HatParty
				rActor.NX_SetEVFo "SOP:rOffSpringPlaced" HatParty
				rActor.NX_SetEVFl "SOP:bPregBirthAnim" 0

				if iDebug == 4
					DebugPrint "Preg4Birth %n: %n: BirthComplete %2.0f" rActor rBirthType iBirthCount
				endif
				Set iBirthstage to 8
				Set iOkToRun to -1

			elseif iBirthStage > 7
				DebugPrint "Preg4Birth %n: ERROR BirthStage %1.0f" rActor iBirthStage

			endif ; *** End Birth Token Stages

			if Sexout.useVoice > 0 && iActorSound > 0
				if iActorSound == 2
					rActor.PlaySound3D SexoutVoiceNs02
				elseif iActorSound == 6
					rActor.PlaySound3D SexoutVoiceNs06
				elseif iActorSound == 7
					rActor.PlaySound3D SexoutVoiceNs07
				elseif iActorSound == 8
					rActor.PlaySound3D SexoutVoiceNs08
				elseif iActorSound == 12
					rActor.PlaySound3D SexoutVoiceNs12
				elseif iActorSound == 14
					rActor.PlaySound3D SexoutVoiceNs14
				endif
				Set iActorSound to 0
			endif ; *** End Actor Birthing Sounds

			rActor.NX_SetEVFl "SOP:iBirthStage" iBirthStage
			if iDebug == 4
				DebugPrint "Preg4Birth %n: %n: BirthType %n, Animation %1.0f, BirthStage %1.0f, BirthCount %1.0f" rActor rPregType rBirthType iBirthAnimation iBirthStage iBirthCount
			endif
		endif ; *** Ok to run?

; *** Actor not OK, Remove Birthing Token
		if iOkToRun < 0
			DebugPrint "Preg4Birth %n: Removing" rActor
			rActor.Dispel SexoutP4EBirthingDue
			rActor.Dispel SexoutP4EBirthingHappening
			rActor.NX_SetEVFl "SOP:iBirthStage" 0
			rActor.NX_SetEVFl "SOP:bPregBirthAnim" 0
			rActor.NX_SetEVFl "SOP:iBirthAnimation" 0
			rActor.NX_SetEVFl "SOP:iBirthCount" 0
			rActor.NX_SetEVFl "SOP:fHoursTillBirth" 0
			rActor.NX_SetEVFo "SOP:rPregType" HatParty
			rActor.NX_SetEVFo "SOP:rBirthType" HatParty
			rActor.NX_SetEVFo "SOP:rOffSpringAdded" HatParty
			rActor.NX_SetEVFo "SOP:rOffSpringPlaced" HatParty
			rActor.RemoveItem SexoutSP4TokenPregTestPositive 9 1
			Set iRemoving to 1
			RemoveMe
		endif ; *** Ok to run?
	endif ;*** rActor & iCnt > iTarget
endif : *** iRemoving < 1 & iPregMainStarted

End

 

saviliana

saviliana

Posted
Posted

Would it be NVSE or its extender updates change some command lines or nx variables names so preg's code didn't doing what they used to do?

 

I think I had seen a notice somewhere around here before last year Xmas that said there were something change to some of the lines in the new nvse extender 14 or later, could be where the issue starts.

 

But I have a very bad memory ( I can't even remember what I eat at lunch, which just happens 2 hours ago.), might could be mistaken with other stuff.

Eciah

Eciah

Posted
Posted

Just wondering since im a total noob at scripting, i noticed after ; *** Remove Animations, Pregnancy & Effects theres a section with a comment there, and its got a ', it changes the color of the text for the rest of the script does that actually effect the script or is it just a coloration deal?

Halstrom

Halstrom

Posted
  • Author
Posted

Just wondering since im a total noob at scripting, i noticed after ; *** Remove Animations, Pregnancy & Effects theres a section with a comment there, and its got a ', it changes the color of the text for the rest of the script does that actually effect the script or is it just a coloration deal?

Just coloration as far as I know anything after a ; is ignored and thrown away when the script is compiled.

Just testing an update now.

RitualClarity

RitualClarity

Posted
Posted

 

Just coloration as far as I know anything after a ; is ignored and thrown away when the script is compiled.

Isn't anything after the ";" just for comments and such. Something like notes?

daralex

daralex

Posted
Posted

Yeah they're still broke, infinite birth animations pretty much atm, but it is recoverable if you let the births happen, then reset the preg vars on the affected characters, then use sexkey or another button-press method of initiating a sex scene on that character, which will break them out of the loop. A couple of things I did notice when it happened, tokens in inventory showed birthing animation stage 2 or 3 where it was sticking. Also the body swap seems to be stacking bodysuits in the inventory many times over(saw one npc in the SO bunker where I set assault to ridiculous numbers on stalking, where she ended up with like 50 P3 stage bodies in inventory).

Sorry to say, I didn't have scof running at the time it happened, however.

saviliana

saviliana

Posted
Posted

 

Just wondering since im a total noob at scripting, i noticed after ; *** Remove Animations, Pregnancy & Effects theres a section with a comment there, and its got a ', it changes the color of the text for the rest of the script does that actually effect the script or is it just a coloration deal?

Just coloration as far as I know anything after a ; is ignored and thrown away when the script is compiled.

Just testing an update now.

 

 

Wait, I've spot something in your post a few days ago...

 

Isn't that " birthanimationremove %1.0f " and " birth complete %2.0f " token in the lower purple zone of the note script should be a running script?

 

It seems you had put it into a note script and stall at that point. ( And it might actaully does, since we all stopping just after regaining control but locked up at droped down position like the script last few working line saids. )

 

I think that " *** prevents NPC's crab walking " should actaully be " *** prevents NPC''s crab walking ".

Halstrom

Halstrom

Posted
  • Author
Posted

Update 20150328.1:

 

SCR:

Added DebugLog print option in MCM

Added Message to remove SCRDebug.esp

Took EyeBot Offspring out of Enclave Faction so hopefully people won't attack them

 

Pregnancy:

Hopefully a fix for a birthing animations by Veniat (unfortunately I haven't had a chance to test myself, been too busy breaking other things and fixing them for last 2 days)

Added Message to remove PregDebug.esp

Some minor fixes my brain can't remember

Fix for the Debugging system not working on next game load

 

OffSpring:

Fix for the Debugging system not working on next game load

Blocked Aggressive Offspring from getting renaming tokens.

Added Message to remove OffSpringDebug.esp

 

Drugging:

Added SetIsPlayable option for tokens when Debugging turned on

Reduced the chances of NPC's drinking alcohol in their inventory

Prep work for it's own MCM

saviliana

saviliana

Posted
Posted

Okay, this time the birth process can be complete without a blockage, but the downside is there is not a single animation.

Tested with coyote and mentits, both have voice and timed text effect, but theres no animation at all.

 

And btw, is that the new after birth bodyswap really that slow? I took 3 days to get rid with 2 mentits eggs' P2body... I don't think that is doing right, compair to last broken version......

SexoutSCRLog-2015-3-28-0-9.txt

Eciah

Eciah

Posted
Posted

I updated to the latest version and I noticed something strange when my character got pregnant, during the pregnancy the Ova token was still in inventory and my character kept getting pregnant Again while pregnant which added more Eggs (Happened with Spore pregnancy and Scorpion pregnancy havent had a chance to test the other pregnancies) not sure if your aware of that happening or not. i didnt see anything in the console that mentioned the ova token but i can try to get a debug log from before pregnancy to after if it will help.

Halstrom

Halstrom

Posted
  • Author
Posted

Okay, this time the birth process can be complete without a blockage, but the downside is there is not a single animation.

Tested with coyote and mentits, both have voice and timed text effect, but theres no animation at all.

 

And btw, is that the new after birth bodyswap really that slow? I took 3 days to get rid with 2 mentits eggs' P2body... I don't think that is doing right, compair to last broken version......

I'll check that debug file out.

 

I updated to the latest version and I noticed something strange when my character got pregnant, during the pregnancy the Ova token was still in inventory and my character kept getting pregnant Again while pregnant which added more Eggs (Happened with Spore pregnancy and Scorpion pregnancy havent had a chance to test the other pregnancies) not sure if your aware of that happening or not. i didnt see anything in the console that mentioned the ova token but i can try to get a debug log from before pregnancy to after if it will help.

Ova's have a MCM setting timer set to 2 or 3 days till expiry so if you have a quick pregnancy they aren't going to go away. Normally humans onlyhave one ova at it deletes itself upon pregnancy, but if you have more, I'm not sure theres's anything there to fade them away during pregnancy or if there is how well it's obviously not working. I don't delete them all immediately to allow for twins, triplets etc.

 

 

I'm testing a fix now, but got side tracked with something else I've broken.

attachicon.gifPreview.jpg

 

Cheeky, How's that Alien Abduction mod going? :)
blackmumba1680

blackmumba1680

Posted
Posted

So I updated to the latest. version of pregnancy and for some reason the NPCs I impregnate are pregnant with some obscene amount of children I'm talking anywhere from 6-13 children, now none of them have reached the stage of actually birthing said children but I'm wondering if when they do will they be stuck in a birthing loop? Now I did not create a new character when I updated

Halstrom

Halstrom

Posted
  • Author
Posted

So I updated to the latest. version of pregnancy and for some reason the NPCs I impregnate are pregnant with some obscene amount of children I'm talking anywhere from 6-13 children, now none of them have reached the stage of actually birthing said children but I'm wondering if when they do will they be stuck in a birthing loop? Now I did not create a new character when I updated

I'm assuming you mean human children, they should be limited to 3 or 4 from memory, I'll check the coding on their limit, excess ones should be removed automatically in theory.

 

Some creatures could have dozens. You can also reset pregnancy now from the MCM.

blackmumba1680

blackmumba1680

Posted
Posted

Well the follower that was pregnant with about 13 kids did loose many of the tokens (maybe I didn't wait long enough for the scripts to start working?) but it didn't go below 3-4, she has 3 female child tokens (I know the tokens are actually called something else) and 3 male child tokens. Do you mean 3-4 for each gender or 3-4 overall? I'll try and post a picture of the follower's inventory however I've never posted a picture here so I don't know if I'll be successful at it.

post-454662-0-59723500-1427556014_thumb.jpg

RitualClarity

RitualClarity

Posted
Posted

 

Cheeky, How's that Alien Abduction mod going? :)

Somebody abducted it.. I can't find it anywhere.. :P

 

I thought you would get a kick out of that jpeg.. lol. I have every confidence that you will fix it and if history is any indication it will be fixed and be better than it ever was before.. ;).

 

Halstrom

Halstrom

Posted
  • Author
Posted

Well the follower that was pregnant with about 13 kids did loose many of the tokens (maybe I didn't wait long enough for the scripts to start working?) but it didn't go below 3-4, she has 3 female child tokens (I know the tokens are actually called something else) and 3 male child tokens. Do you mean 3-4 for each gender or 3-4 overall? I'll try and post a picture of the follower's inventory however I've never posted a picture here so I don't know if I'll be successful at it.

attachicon.gif2015-03-28_00002.jpg

Ahh. those bottom 2 "Human" tokens aren't pregnancies they are just flags for pregnancy check dialogue usage, you actually only have 6 pregnancies there total, the actual pregnancy tokens are always specific to their type and gender unless they are eggs in which case it's random gender at hatching.

Maybe I think I have the limit set at 3 of each type somehow, I'll look into making the ova delete themselves when they hit a limit.

blackmumba1680

blackmumba1680

Posted
Posted

 

Well the follower that was pregnant with about 13 kids did loose many of the tokens (maybe I didn't wait long enough for the scripts to start working?) but it didn't go below 3-4, she has 3 female child tokens (I know the tokens are actually called something else) and 3 male child tokens. Do you mean 3-4 for each gender or 3-4 overall? I'll try and post a picture of the follower's inventory however I've never posted a picture here so I don't know if I'll be successful at it.

attachicon.gif2015-03-28_00002.jpg

Ahh. those bottom 2 "Human" tokens aren't pregnancies they are just flags for pregnancy check dialogue usage, you actually only have 6 pregnancies there total, the actual pregnancy tokens are always specific to their type and gender unless they are eggs in which case it's random gender at hatching.

Maybe I think I have the limit set at 3 of each type somehow, I'll look into making the ova delete themselves when they hit a limit.

 

Since the update I have yet to see this problem with any NEW pregnancy's, so I don't know, 

Guest
This topic is now closed to further replies.
Go to topic listing

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...