Redwater Den

[Gearknot]

When completing the bloodstone chalice quest the state of Redwater Den changes to a lifeless static vampire hole.

 

I've been trying to find what activator this is set on because I would like to make a mod that keeps this change from happening as I really enjoyed the atmosphere they had inside that place before the quest was done.

 

Really, why everything changes makes no sense to me, there isn't any reason the business should close down, the vampires always need fresh meat.

 

I think i've found the activator (DLC1dunRedwaterDenSpringActivator) in the bloodspring only I cannot open the script to read what it is doing.

 

The error says- Windows cannot find DLC1dunRedwaterDenBloodspring I've looked in the folder it is suppose to be in and it is not there.

 

Anyone know anything about this? Why or how I could get this done? Any help would be really appreciated.

 

Was also trying to get this to work for a saved game that has the quest completed already.

 

[mybrainhurts]

If the script is in a bsa file (and it is, afaik) you won't be able to examine it without extracting the bsa. Info on extraction is here.

 

Edit: Actually, no. It's in the data/scripts/source directory:

 

 

ScriptName DLC1dunRedwaterDenBloodspringScript extends objectReference
{This script manages drinking from the pool and filling the chalice for the vampire radiant quest}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;      Properties block
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Spell Property DLC1VampireChalicePower auto
Spell Property DLC1dunRedwaterDenPower auto


GlobalVariable Property DLC1dunRedwaterDenPowerStopDay auto
GlobalVariable Property GameDaysPassed auto
GlobalVariable Property PlayerIsVampire auto

;Disease the player may be infected with
Spell Property TrapDiseaseAtaxia auto
Spell Property TrapDiseaseBoneBreakFever auto
Spell Property TrapDiseaseBrainRot auto
Spell Property TrapDiseaseRattles auto
Spell Property TrapDiseaseRockjoint auto
Spell Property TrapDiseaseWitbane auto
Spell Property TrapDiseaseSanguinareVampiris auto

Message Property DLC1dunRedwaterDenTaintedBloodMessage auto
Message Property DLC1dunRedwaterDenVHQBloodMessage auto

float property diseaseChance = 100.0 auto
float property vampChance = 100.0 auto

Quest property DLC1VampireBaseIntro auto

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;       Event Block
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;Register for update is used to for clearing power/withdrawal
Event OnUpdateGameTime()
        
        ;Play time with power is up, time to give withdrawals
    debug.Trace(self + ": UpdateGameTime has fired")
    if (Game.GetPlayer() as Actor).HasSpell(DLC1dunRedwaterDenPower)
        debug.Trace(self + ": Player has power, now remove it")
        Game.GetPlayer().RemoveSpell(DLC1dunRedwaterDenPower)
        ;here is where we register for the update to remove the withdrawals and add the withdrawals
    endif

EndEvent

;On activate by the player check if the player already has the power or the chalice version
Event OnActivate(ObjectReference ActivateRef)
    if DLC1VampireBaseIntro.getStage() == 30
        ;the quest is running so you are filling the chalice, the script for this is assigned through an alias on the quest

    ;If we are not at the stage in the quest to fill the chalice, do the rest of the stuff
    elseif ActivateRef == game.getPlayer()
        ;Silly vampire you already have the version with no withdrawals, you don't want this
        if game.getPlayer().hasSpell(DLC1VampireChalicePower)
            DLC1dunRedwaterDenVHQBloodMessage.Show()
        ;You already have the power, go away
        elseif Game.GetPlayer().HasSpell(DLC1dunRedwaterDenPower)
            DLC1dunRedwaterDenTaintedBloodMessage.Show()
        ;if neither of the above are true, then drink from the spring
        else
            DrinkFromPool()
        endif
    endif
endEvent

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;      Function block
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

function DrinkFromPool()
    ;if the player is a vampire give them the Tainted Blood of the Ancients
    if PlayerIsVampire.getValue() == 1
        float today = GameDaysPassed.GetValue()
        float PowerStopDay = today + 1
        ;If you have withdrawals currently we can get rid of those
        
        DLC1dunRedwaterDenPowerStopDay.SetValue(PowerStopDay)
        RegisterForSingleUpdateGameTime(24 * 1)
        Game.GetPlayer().AddSpell(DLC1dunRedwaterDenPower)
    ;If the player is NOT a vampire, infect them with diseases. Really what did you expect.
    else
        ProcessInfection(game.GetPlayer())
    endif
EndFunction


Function ProcessInfection (actor myTarget)
        if utility.randomFloat(0.0, 100.0) <= diseaseChance
            int diseasePick        
            diseasePick = utility.randomInt(1,6)
            ;infect with a random disease
            if diseasePick == 1
                myTarget.DoCombatSpellApply(TrapDiseaseAtaxia, myTarget)
            elseif diseasePick == 2
                myTarget.DoCombatSpellApply(TrapDiseaseBoneBreakFever, myTarget)
            elseif diseasePick == 3
                myTarget.DoCombatSpellApply(TrapDiseaseBrainRot, myTarget)
            elseif diseasePick == 4
                myTarget.DoCombatSpellApply(TrapDiseaseRattles, myTarget)
            elseif diseasePick == 5
                myTarget.DoCombatSpellApply(TrapDiseaseRockjoint, myTarget)
            elseif diseasePick == 6
                myTarget.DoCombatSpellApply(TrapDiseaseWitbane, myTarget)
            endif
        endif
        
        ;Separate chance of infection with vampirism
        if utility.randomFloat(0.0, 100.0) <= vampChance
            myTarget.DoCombatSpellApply(TrapDiseaseSanguinareVampiris, myTarget)
        endif
endFunction

;/
;Containment for stuff that needs to be added to the chalice

Spell Property DLC1dunRedwaterDenPower auto
Spell Property DLC1dunRedwaterDenWithdrawl auto
GlobalVariable Property DLC1dunRedwaterDenPowerStopDay auto
GlobalVariable Property DLC1dunRedwaterDenWithdrawalStopDay auto

    if Game.GetPlayer().HasSpell(DLC1dunRedwaterDenPower)
        Game.GetPlayer().RemoveSpell(DLC1dunRedwaterDenPower)
        DLC1dunRedwaterDenPowerStopDay.SetValue(today - 1)
    endif
    if Game.GetPlayer().HasSpell(DLC1dunRedwaterDenWithdrawl)
        Game.GetPlayer().RemoveSpell(DLC1dunRedwaterDenWithdrawl)
        DLC1dunRedwaterDenWithdrawalStopDay.SetValue(today - 1)
    endif
/;

 

[Gearknot]

Hrm, thanks, i thought i searched that once maybe i mispelled something, I have found it in the folder. But whats the reason I can't edit the source in the creation kit?

 

And upon looking at that and a couple other things it doesn't even look like what i need now anyways. Not sure where to go on this now.

[Gearknot]

Nevermind, all i had to do was move the thing out from a dawnguard folder into the main source folder, fixed that.

 

Going to continue to work on this anyone that would like to offer a hand at figuring out what i need to do, I would be in debt to them.